home *** CD-ROM | disk | FTP | other *** search
/ Sprite 1984 - 1993 / Sprite 1984 - 1993.iso / lib / mkmf / mkmf.script < prev    next >
Text File  |  1991-04-11  |  1KB  |  56 lines
  1. #!/sprite/cmds/csh -f
  2. #
  3. # A script to generate (or regenerate) the Makefile for a directory
  4. # consisting solely of a shell script.
  5. #
  6. # We assume we were invoked from mkmf.  Parameters passed in from mkmf
  7. # through environment variables:
  8. #
  9. #    MKMFDIR        directory containing prototype makefiles
  10. #    MAKEFILE    name of makefile to create
  11. #    SUBTYPE        additional information, telling whether this
  12. #            is an X directory, Sprite directory, etc.
  13. #
  14.  
  15. #
  16. # Argument processing.  (Generalized form, even though just one flag so far.)
  17. #
  18. while ($#argv >= 1)
  19.     if ("$1" == '-x') then
  20.     set echo
  21.     endif
  22.     shift
  23. end
  24.  
  25. set subtype=$SUBTYPE
  26. set prog=$cwd:t
  27. set machines=`grep -v "^#" /sprite/admin/machineTypes`
  28. set makefile=$MAKEFILE
  29. set distdir=($DISTDIR)
  30.  
  31. if (-e $makefile.proto) then
  32.     set proto=$makefile.proto
  33. else
  34.     set proto="${MKMFDIR}/Makefile.script"
  35. endif
  36.  
  37. echo "Generating $makefile for $prog using $proto"
  38.  
  39. set nonomatch
  40. set manPages = (*.man)
  41. if ("$manPages" == "*.man") then
  42.     set manPages = ()
  43. endif
  44. unset nonomatch
  45.  
  46. cat $proto | sed \
  47.     -e "s,@(DATE),`date`,g" \
  48.     -e "s,@(MACHINES),$machines,g" \
  49.     -e "s,@(MAKEFILE),$makefile,g" \
  50.     -e "s,@(MANPAGES),$manPages,g" \
  51.     -e "s,@(NAME),$prog,g" \
  52.     -e "s,@(TEMPLATE),$proto,g" \
  53.     -e "s,@(TYPE),$subtype,g" \
  54.     -e "s,@(DISTDIR),$distdir,g" \
  55.     > $makefile
  56.